Papervision3DのMovieMaterialを使ってテクスチャを生成する方法

MovieMaterial(asset:*, transparent:Boolean = false, initObject:Object = null)

var mc:MovieClip = new MovieClip();

addChild(child:DisplayObject):DisplayObject

var txt_field:TextField = new TextField();
var format:TextFormat = new TextFormat("Impact", size, color);
txt_field.text = "adamrocker";
txt_field.autoSize = TextFieldAutoSize.LEFT;
txt_field.setTextFormat(format);

private function get_clip(text:String, color:Number):MovieClip {
  var format:TextFormat = new TextFormat("Impact", size, color);
  var txt_field:TextField = new TextField();
  var mc:MovieClip = new MovieClip();
 
  txt_field.text = text;
  txt_field.autoSize = TextFieldAutoSize.LEFT;
  txt_field.setTextFormat(format);
  mc.addChild(txt_field);
 
  return mc;
}

var mc:MovieClip = get_clip("adamrocker", 0xcccccc);
material = new MovieMaterial(mc, true);
material.doubleSided = true;

package {
  import flash.display.*;
  import flash.events.*;
  import flash.text.*;
  import flash.display.Sprite;
  import org.papervision3d.core.proto.*;
  import org.papervision3d.scenes.MovieScene3D;
  import org.papervision3d.objects.Plane;
  import org.papervision3d.materials.MovieMaterial;
  import org.papervision3d.cameras.Camera3D;
  import org.papervision3d.objects.DisplayObject3D;
 
  [SWF(
       backgroundColor="0xffffff",
       frameRate="45"
      )]
 
  public class MyMovieClip extends Sprite
  {
    //each object parameters
    private var size      :int = 240;
    private var obj_segw  :int = 1;
    private var obj_segh  :int = 1;
 
    //global object
    private var container :Sprite;
    private var scene     :SceneObject3D;
    private var camera    :CameraObject3D;
    private var obj       :DisplayObject3D;
    private var material  :MaterialObject3D;
 
    public function MyMovieClip()
    {
      //ステージ
      this.stage.quality   = "MEDIUM";
      this.stage.scaleMode = "noScale";
      this.stage.align = StageAlign.TOP_LEFT;
      this.stage.addEventListener(Event.ENTER_FRAME, loop);
      this.stage.addEventListener(Event.RESIZE, resize);
 
      //コンテナ生成
      container = new Sprite();
      container.x = this.stage.stageWidth  / 2;
      container.y = this.stage.stageHeight / 2;
      addChild(container);
 
      //シーン生成
      scene = new MovieScene3D(container);
 
      //マテリアルの生成
      var mc:MovieClip = get_clip("adamrocker", 0xcccccc);
      material = new MovieMaterial(mc, true);
      material.doubleSided = true;
 
      //オブジェクトの生成
      obj = new Plane(material, size, size, obj_segw, obj_segh);
      scene.addChild(obj);
 
      //カメラ設定
      camera = new Camera3D();
      camera.z = size * 1.1;
      camera.zoom = 1.5;
 
      this.stage.addEventListener(Event.ENTER_FRAME, loop);
      this.stage.addEventListener(Event.RESIZE, resize);
      resize(null);
    }
 
    //--------------------------------------------------get_clip    
    private function get_clip(text:String, color:Number):MovieClip {
      var format:TextFormat = new TextFormat("Impact", size, color);
      var txt_field:TextField = new TextField();
      var mc:MovieClip = new MovieClip();
 
      txt_field.text = text;
      txt_field.autoSize = TextFieldAutoSize.LEFT;
      txt_field.setTextFormat(format);
      mc.addChild(txt_field);
 
      return mc;
    }
 
    //--------------------------------------------------loop  
    private function loop(e:Event):void {
      // 回転
      obj.rotationY += container.mouseY / 100;
      obj.rotationX += container.mouseX / 100;
 
      //再レンダリング
      scene.renderCamera(camera)
    }
 
    //-------------------------------------------------stage
    private function resize(e:Event):void {
      container.x = this.stage.stageWidth  / 2;
      container.y = this.stage.stageHeight / 2;
    }
  }
}