Papervision3Dでプリミティブ以外のオブジェクトを作る

obj = new Mesh3D(material, new Array(), new Array(), null);

material = new ColorMaterial(0xcccccc,1.0);

obj.geometry.vertices.push(new Vertex3D(size*cos(90), size*sin(90), 0));
obj.geometry.vertices.push(new Vertex3D(size*cos(210), size*sin(210), 0));
obj.geometry.vertices.push(new Vertex3D(size*cos(330), size*sin(330), 0));

private function sin(degree : Number):Number{
  return Math.sin(Math.PI * degree / 180);
}
 
private function cos(degree : Number):Number{
  return Math.cos(Math.PI * degree / 180);
}

obj.geometry.faces.push(new Face3D(obj.geometry.vertices, null, null));
obj.geometry.ready = true;

package {
  import flash.display.*;
  import flash.events.*;
 
  import org.papervision3d.core.proto.*;
  import org.papervision3d.core.geom.*;
  import org.papervision3d.scenes.*;
  import org.papervision3d.objects.*;
  import org.papervision3d.cameras.*;
  import org.papervision3d.materials.*;
 
  [SWF(
       backgroundColor="0xffffff",
       frameRate="45"
      )]
 
  public class Mesh3DPlane extends Sprite
  {
    private var container : Sprite;
    private var scene     : Scene3D;
    private var camera    : Camera3D;
    private var rootNode  : DisplayObject3D;
    private var obj       : DisplayObject3D ; //オブジェクト
    private var size      : int = 200;//オブジェクトの長さ
    private var segment   : int = 1;  //面の分割数
    private var material  : MaterialObject3D;
 
    //--------------------------------------------Constructor
    public function Mesh3DPlane():void
    {
      //ステージ
      this.stage.quality   = "MEDIUM";
      this.stage.scaleMode = "noScale";
      this.stage.align = StageAlign.TOP_LEFT;
      this.stage.addEventListener(Event.ENTER_FRAME, loop);
      this.stage.addEventListener(Event.RESIZE, resize);
 
      //コンテナ生成
      container = new Sprite();
      container.x = this.stage.stageWidth  / 2;
      container.y = this.stage.stageHeight / 2;
      this.addChild(container);
 
      //シーン生成
      scene = new Scene3D(container);
 
      //rootNode生成
      rootNode = new DisplayObject3D("rootNode");
      scene.addChild(rootNode);
 
      //マテリアル設定
      material = new ColorMaterial(0xcccccc,1.0);
      material.name = "white";
      material.doubleSided = true;
 
      //メッシュを作成
      obj = new Mesh3D(material, new Array(), new Array(), null);
 
      //頂点
      obj.geometry.vertices.push(new Vertex3D(size*cos(90), size*sin(90), 0));
      obj.geometry.vertices.push(new Vertex3D(size*cos(210), size*sin(210), 0));
      obj.geometry.vertices.push(new Vertex3D(size*cos(330), size*sin(330), 0));
 
      //面を作成
      obj.geometry.faces.push(new Face3D(obj.geometry.vertices, null, null));
      obj.geometry.ready = true;
 
      rootNode.addChild(obj);
 
      //camera設定
      camera = new Camera3D();
      camera.y = size;
      camera.z = -size * 2;
      camera.focus = 300;
      camera.zoom = 1;
    }
 
    //--------------------------------------------loop 
    private function loop(event:Event):void
    {
      // 回転
      obj.rotationY += container.mouseY / 100;
      obj.rotationX += container.mouseX / 100;
 
      //再レンダリング
      scene.renderCamera(camera);
    }
 
    //--------------------------------------------stage
    private function resize(e:Event):void{
      container.x = this.stage.stageWidth  / 2;
      container.y = this.stage.stageHeight / 2;
    }
 
    //--------------------------------------------sin
    private function sin(degree:Number):Number{
      return Math.sin(Math.PI * degree / 180);
    }
 
    //--------------------------------------------cos
    private function cos(degree:Number):Number{
      return Math.cos(Math.PI * degree / 180);
    }
  }
}