Papervision3Dのオブジェクトを半透明化する

new ColorMaterial(0xff0000,0.5);

public function ColorMaterial( color:Number=0xFF00FF, alpha:Number = 1, initObject:Object=null )
{
   super( initObject );
 
   this.fillColor = color;
   this.fillAlpha = alpha;
}

package {
  import flash.display.*;
  import flash.events.*;
 
  import org.papervision3d.core.proto.*;
  import org.papervision3d.scenes.*;
  import org.papervision3d.objects.*;
  import org.papervision3d.cameras.*;
  import org.papervision3d.materials.*;
 
  [SWF(
       backgroundColor="0xffffff",
       frameRate="45"
      )]
 
  public class AlphaPlane extends Sprite
  {
    private var container : Sprite;
    private var scene     : Scene3D;
    private var camera    : Camera3D;
    private var rootNode  : DisplayObject3D;
    private var obj1      : DisplayObject3D ; //オブジェクト
    private var obj2      : DisplayObject3D ; //オブジェクト
    private var size      : int = 200;//オブジェクトの長さ
    private var segment   : int = 1;  //面の分割数
    private var material1 : MaterialObject3D;
    private var material2 : MaterialObject3D;
 
    //--------------------------------------------Constructor
    public function AlphaPlane():void
    {
      //ステージ
      this.stage.quality   = "MEDIUM";
      this.stage.scaleMode = "noScale";
      this.stage.align = StageAlign.TOP_LEFT;
      this.stage.addEventListener(Event.ENTER_FRAME, loop);
      this.stage.addEventListener(Event.RESIZE, resize);
 
      //コンテナ生成
      container = new Sprite();
      container.x = this.stage.stageWidth  / 2;
      container.y = this.stage.stageHeight / 2;
      this.addChild(container);
 
      //シーン生成
      scene = new Scene3D(container);
 
      //rootNode生成
      rootNode = new DisplayObject3D("rootNode");
      scene.addChild(rootNode);
 
      //マテリアル1設定
      material1 = new ColorMaterial(0xff0000, 0.5);
      material1.name = "red";
      material1.doubleSided = true;
 
       //マテリアル2設定
      material2 = new ColorMaterial(0x0000ff, 0.5);
      material2.name = "blue";
      material2.doubleSided = true;
 
      //オブジェクト1生成
      obj1 = new Plane(material1, size, size, segment, segment);
      obj1.x = -size;
      rootNode.addChild(obj1);
 
      //オブジェクト2生成
      obj2 = new Plane(material2, size, size, segment, segment);
      obj2.x = size;
      obj1.addChild(obj2);
 
      //camera設定
      camera = new Camera3D();
      camera.z = -size * 2;
      camera.focus = 300;
      camera.zoom = 1;
 
      //イベントリスナの登録			
      container.addEventListener(MouseEvent.CLICK, clickObj);
    }
 
    //--------------------------------------------loop 
    private function loop(event:Event):void
    {
      // 回転
      obj1.rotationY += container.mouseY / 100;
      obj1.rotationX += container.mouseX / 100;
      obj2.rotationY -= container.mouseY / 100;
      obj2.rotationX -= container.mouseX / 100;
 
      //再レンダリング
      scene.renderCamera(camera);
    }
 
    //--------------------------------------------stage
    private function resize(e:Event):void
    {
      container.x = this.stage.stageWidth  / 2;
      container.y = this.stage.stageHeight / 2;
    }
 
    //--------------------------------------------mouse click	
    private function clickObj (e:MouseEvent):void
    {
      var material  : MaterialObject3D;
      material = obj1.material;
      obj1.material = obj2.material;
      obj2.material = material;
      scene.renderCamera(camera);
    }
  }
}